로드 조작중에, 이미 로드 끝난 데이터의 바이트수를 나타냅니다.

다운로드 데이터의 합계 바이트수를 나타냅니다. 이 property는, 로드 조작의 진행중은 0 을 포함해, 조작이 완료한 시점에서 설정됩니다.

로드 조작에 의해 수신한 데이터입니다. 이 property는, 로드 조작이 완료했을 때에만 설정됩니다. 데이터의 형식은,dataFormat property의 설정에 의해 정해집니다.

dataFormat property가 URLLoaderDataFormat.TEXT 의 경우, 받는 데이터는, 로드 된 파일의 텍스트를 포함한 string입니다.

dataFormat property가 URLLoaderDataFormat.BINARY 의 경우, 받는 데이터는, 생의 바이너리 데이터를 포함한 ByteArray object입니다.

dataFormat property가 URLLoaderDataFormat.VARIABLES 의 경우, 받는 데이터는, URL encode 된 변수를 포함한 URLVariables object입니다.

See also

다운로드한 데이터가 텍스트 (URLLoaderDataFormat.TEXT), 생의 바이너리 데이터 (URLLoaderDataFormat.BINARY), 또는 URL encode 된 변수 (URLLoaderDataFormat.VARIABLES)의 머지않아인지를 제어합니다.

dataFormat property의 값이 URLLoaderDataFormat.TEXT 의 경우, 받는 데이터는, 로드 된 파일의 텍스트를 포함한 string입니다.

dataFormat property의 값이 URLLoaderDataFormat.BINARY 의 경우, 받는 데이터는, 생의 바이너리 데이터를 포함한 ByteArray object입니다.

dataFormat property의 값이 URLLoaderDataFormat.VARIABLES 의 경우, 받는 데이터는, URL encode 된 변수를 포함한 URLVariables object입니다.

디폴트치URLLoaderDataFormat.TEXT.

See also

URLLoader object를 작성합니다.

See also

진행중의 로드 조작은 즉시 종료합니다. 진행중의 로드 조작은 즉시 종료합니다. URL 가 현재 스트리밍되어 있지 않은 경우, 무효인 스트림(Stream) 에러가 슬로우 됩니다.

지정된 URL 로부터 데이터를 송신 및 로드합니다. dataFormat property로 설정한 값에 근거해, 텍스트, 생의 바이너리 데이터, 또는 URL encode 된 변수로서 데이터를 받을 수가 있습니다. dataFormat property의 디폴트치는 텍스트입니다. 데이터가 지정된 URL 에 송신하는 경우는, URLRequest object의 data property를 설정할 수 있습니다.

메모:로드안의 파일에 ASCII 캐릭터 이외의 캐릭터 (영어 이외가 많은 언어에 존재한다)가 포함되어 있는 경우는, ASCII 와 같은 비 Unicode 형식은 아니고 UTF-8 또는 UTF-16 인코딩 형식에서 파일을 보존하는 것을 추천합니다.

이 Methods를 사용할 때는, Flash Player 시큐러티 모델을 고려해 주세요.

Flash Player 8 이후 :

• 호출원 SWF 파일이 로컬 파일 시스템의 샌드 박스에 있어, 타겟 리소스가 네트워크상의 샌드 박스에 있는 경우, 데이터를 로드할 수 없습니다.
• 호출원 SWF 파일이 네트워크상의 샌드 박스에 있어, 타겟 리소스가 로컬에 있는 경우, 데이터를 로드할 수 없습니다.

Flash Player 7 이후에서는, 크로스 도메인 policy 파일에 의해, Web 사이트에서의 리소스에의 크로스 도메인 액세스를 허가할 수가 있습니다. Flash Player 7 이후에 SWF 파일을 실행하고 있는 경우,url 는 정확하게 같은 도메인에 놓여져 있을 필요가 있습니다. 예를 들어 www.adobe.com 에 놓여져 있는 SWF 파일은, www.adobe.com 에 놓여져 있는 소스로부터 전용 데이터를 로드할 수 있습니다.

상세한 것에 대하여는, 다음의 주제를 참조해 주세요.

• 「ActionScript 3.0 의 프로그래밍」의시큐러티의 장과 LiveDocs 의 최신 코멘트
• Flash Player 9 시큐러티에 관한 화이트 페이퍼

See also

수신한 모든 데이터가 디코드되어 URLLoader object의 data property에 배치된 후에 dispatch됩니다. 이 이벤트가 dispatch되면, 수신한 데이터에 액세스 할 수 있습니다.

complete event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

URLLoader.load() 를 호출해 HTTP 를 개입시켜 데이터에 액세스를 시도해 현재의 Flash Player 환경에서 요구의 스테이터스 코드를 검출해 돌려줄 수가 있는 경우에 dispatch됩니다(일부의 브라우저 환경에서는 이 정보를 제공할 수 없습니다). httpStatus 이벤트가 있는 경우는,complete event 또는 error 이벤트의 전에, 이러한 이벤트에 가세해 송신됩니다.

httpStatus event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

URLLoader.load() 의 호출에 의해 다운로드가 종료한다고 하는 값명적인 에러가 발생하는 경우에 dispatch됩니다.

ioError event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

URLLoader.load() Methods의 호출에 의해 다운로드 처리가 개시되면 dispatch됩니다.

open event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

다운로드 처리를 실행중에 데이터를 수신했을 때에 dispatch됩니다.

URLLoader object에서는, 완전하게 데이터가 수신될 때까지는 데이터에 액세스 할 수 없습니다. 이 때문에, progress 이벤트의 통지로 밖에 다운로드의 진행 상황을 확인할 수 없습니다. 완전하게 다운로드되기 전에 데이터에 액세스 하려면 , URLStream object를 사용합니다.

progress event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

URLLoader.load() 의 호출에 의해 시큐러티 샌드 박스의 외부에 있는 서버로부터 데이터를 로드하려고 하면 dispatch됩니다.

SecurityErrorEvent.SECURITY_ERROR 정수는,securityError event object의 type property치를 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

See also

메모: 이 예를 실행하려면 , urlLoaderExample.txt (이)라는 이름의 파일을 SWF 파일과 같은 디렉토리에 배치합니다. 이 파일에는, 다음의 텍스트행만이 포함되어 있습니다.

answer=42&question=unknown

코드예에서는, 다음의 처리가 실행됩니다.

1. constructor　 　 함수는 loader 라고 하는 URLLoader 인스턴스와 request 라고 하는 URLRequest 인스턴스를 작성합니다. 이것은 로드 되는 파일의 장소와 이름입니다.
2. loader object가 configureListeners() Methods에게 건네져 지원(support)되는 각 URLLoader 이벤트에 listener를 추가합니다.
3. 다음에 request object가, 텍스트 파일을 로드하는 loader.load() 에게 건네집니다.
4. URLLoader 에 의한 텍스트 파일의 로드가 종료하면,Event.COMPLETE event 가 발생해, completeHandler() Methods가 방아쇠 됩니다. completeHandler() Methods는, 파일로부터 로드 된 텍스트로부터 URLVariables object를 작성합니다. URLVariables object는, URL encode 된 이름과 값의 페어를 ActionScript property로 변환해, 로드 된 데이터를 조작하기 쉽게 합니다.

package {
    import flash.display.Sprite;
    import flash.events. *;
    import flash.net. *;

    public class URLLoaderExample extends Sprite {
        public function URLLoaderExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("urlLoaderExample.txt");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document. ");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher) :void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event) :void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
    
            var vars:URLVariables = new URLVariables(loader.data);
            trace("The answer is " + vars.answer);
        }

        private function openHandler(event:Event) :void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent) :void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent) :void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent) :void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent) :void {
            trace("ioErrorHandler: " + event);
        }
    }
}