true 로 설정되어 텍스트 필드에 포커스가 없는 경우, 텍스트 필드내의 선택 내용은 회색으로 하이라이트 표시됩니다. false 로 설정되어 텍스트 필드에 포커스가 없는 경우, 텍스트 필드내의 선택 내용은 하이라이트 표시되지 않습니다.

디폴트치false.

See also

    package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_alwaysShowSelection extends Sprite {
        public function TextField_alwaysShowSelection() {
            var label1:TextField = createTextField(0, 20, 200, 20);
            label1.text = "This text is selected. ";
            label1.setSelection(0, 9);
            label1.alwaysShowSelection = true;

            var label2:TextField = createTextField(0, 50, 200, 20);
            label2.text = "Drag to select some of this text. ";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x; result.y = y;
            result.width = width; result.height = height;
            addChild(result);
            return result;
        }
    }
}

이 텍스트 필드에 사용되는 에일리어징 제거 처리의 타입입니다. 이 property에는,flash.text.AntiAliasType 정수를 사용합니다. 이 설정은, 폰트가 포함되고 있는 (embedFonts property가 true 로 설정되어 있다) 경우에게만 제어할 수 있습니다. 디폴트 설정은,flash.text.AntiAliasType.ADVANCED 입니다.

이 property의 값을 설정하려면 , 다음의 string치를 사용합니다.

See also

텍스트 필드의 자동적인 확대·축소 및 정렬을 제어합니다. TextFieldAutoSize 정수의 유효한 값은 다음과 같습니다. TextFieldAutoSize.NONE (디폴트),TextFieldAutoSize.LEFT,TextFieldAutoSize.RIGHT, 및 TextFieldAutoSize.CENTER.

autoSize 가 TextFieldAutoSize.NONE (디폴트치)로 설정되어 있으면, 크기 변경은 행해지지 않습니다.

autoSize 를 TextFieldAutoSize.LEFT 로 설정하면, 텍스트는 왼쪽 가지런히 하고 텍스트로서 다루어집니다. 즉, 텍스트 필드의 왼쪽 마진이 고정되어 텍스트 필드의 단일행의 오른쪽 마진만이 신축합니다. 텍스트에 개행 ("\n" 또는 "\r" 등)이 포함되는 경우, 텍스트의 다음의 행이 들어가도록(듯이) 필드의 아래 쪽도 확장됩니다. wordWrap 도 true 로 설정했을 경우, 텍스트 필드의 아래 쪽만이 신축해, 우측은 고정된 채로 있습니다.

autoSize 를 TextFieldAutoSize.RIGHT 로 설정하면, 텍스트는 오른쪽맞춤 텍스트로서 다루어집니다. 즉, 텍스트 필드의 오른쪽 마진이 고정되어 텍스트 필드의 단일행의 왼쪽 마진만이 신축합니다. 텍스트에 개행 ("\n" 또는 "\r" 등)이 포함되는 경우, 텍스트의 다음의 행이 들어가도록(듯이) 필드의 아래 쪽도 확장됩니다. wordWrap 도 true 로 설정했을 경우, 텍스트 필드의 아래 쪽만이 신축해, 좌측은 고정된 채로 있습니다.

autoSize 를 TextFieldAutoSize.CENTER 로 설정하면, 텍스트는 centering 텍스트로서 다루어집니다. 즉, 텍스트 필드의 단일행의 크기 변경을 실시하면, 좌우 양마진이 균등하게 신축됩니다. 텍스트에 개행 ("\n" 또는 "\r" 등)이 포함되는 경우, 텍스트의 다음의 행이 들어가도록(듯이) 필드의 아래 쪽도 확장됩니다. wordWrap 도 true 로 설정했을 경우, 텍스트 필드의 아래 쪽만이 신축해, 좌우 양측은 고정된 채로 있습니다.

See also

텍스트 필드에 배경의 칠이 있을지 어떨지를 지정합니다. true 인 경우, 텍스트 필드에 배경의 칠이 있습니다. false 인 경우, 텍스트 필드에는 배경의 칠이 없습니다. backgroundColor property를 사용해, 텍스트 필드의 배경색을 설정합니다.

디폴트치false.

See also

텍스트 필드의 배경의 색입니다. 디폴트치는 0xFFFFFF (흰색)입니다. 이 property는, 현재 배경이 없는 경우에서도 취득 또는 설정할 수 있습니다. 다만, 배경의 색이 표시되는 것은 텍스트 필드의 background property가 true 로 설정되어 있는 경우만입니다.

See also

텍스트 필드에 경계선이 있을지 어떨지를 지정합니다. true 인 경우, 텍스트 필드에 경계선이 있습니다. false 인 경우, 텍스트 필드에 경계선이 없습니다. borderColor property를 사용해, 경계선의 색을 설정합니다.

디폴트치false.

See also

텍스트 필드의 경계선의 색입니다. 디폴트치는 0x000000 (흑)입니다. 이 property는, 현재 경계선이 없는 경우에서도 취득 또는 설정할 수 있습니다. 다만, 경계선의 색이 표시되는 것은 텍스트 필드의 border property가 true 로 설정되어 있는 경우만입니다.

See also

지정된 텍스트 필드의 현재 보기 범위에서 맨 마지막 줄을 나타내는 정수입니다 (1 으로부터 시작되는 인덱스). 텍스트 필드는, 텍스트의 블록에 씌운 윈도우와 같은 것입니다. scrollV property는, 그 윈도우에 표시되고 있는 선두행을 나타내는 인덱스입니다 (1 으로부터 시작되는 인덱스).

scrollV 와 bottomScrollV 로 나타나는 행의 사이의 모든 텍스트가, 텍스트 필드에 현재 표시되고 있습니다.

See also

커서 (caret) 위치의 인덱스입니다. 커서가 표시되어 있지 않은 경우, 값은, 포커스를 필드에 되돌렸을 경우에 커서가 표시되는 위치를 나타냅니다. 통상은, 커서의 마지막 위치를 나타냅니다. 필드에 포커스가 없었던 경우는, 0 을 나타냅니다.

선택 범위의 인덱스는 제로로부터 시작됩니다. 즉, 제 1 의 위치는 0, 제 2 의 위치는 1, 이하 와 같습니다.

See also

이 예를 실행해, TextField 를 클릭해 텍스트의 선택을 시도합니다. 다음에, 텍스트를 선택하지 않고 필드를 클릭합니다. 선택하지 않고 텍스트를 클릭했을 경우, caretIndex property는 커서가 표시되는 위치를 나타내, selectionBeginIndex selectionEndIndex property는 caretIndex property의 값과 동일해집니다.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field.  Compare the difference between clicking without selecting versus clicking and selecting text. ";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent) :void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

HTML 텍스트를 가지는 텍스트 필드내의 여분의 공백 (스페이스, 개행등)을 삭제할지 어떨지를 지정하는 불리언 값입니다. 디폴트치는 false 입니다. condenseWhite property는,text property는 아니고 htmlText property로 설정된 텍스트에게만 영향을 줍니다. text property로 텍스트를 설정했을 경우,condenseWhite 는 무시됩니다.

condenseWhite 를 true 로 설정했을 경우는, 텍스트 필드내에서 개행을 지정할 경우에 <BR> 나 <P> 등의 표준의 HTML 커멘드를 사용할 필요가 있습니다.

condenseWhite property는 htmlText property를 설정하기 전으로 설정합니다.

See also

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_condenseWhite extends Sprite {
        public function TextField_condenseWhite() {
            var tf1:TextField = createTextField(0, 0, 200, 50);
            tf1.condenseWhite = false;
            tf1.htmlText = "keep    on\n\ttruckin'";
            
            var tf2:TextField = createTextField(0, 120, 200, 50);
            tf2.condenseWhite = true;
            tf2.htmlText = "keep    on\n\ttruckin'";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

새롭게 삽입하는 텍스트 (replaceSelectedText() Methods로 삽입한 텍스트 또는 유저가 입력한 텍스트등)에 적용하는 포맷을 지정합니다.

defaultTextFormat property에 액세스 하면, 모든 property가 정의된 TextFormat object가 돌려주어집니다. null 의 property는 없습니다.

See also

텍스트 필드가 패스워드 텍스트 필드일지 어떨지를 지정합니다. 이 property의 값이 true 인 경우, 텍스트 필드는 패스워드 텍스트 필드로서 다루어져 입력된 캐릭터는 실제의 캐릭터 대신에 asterisk로 숨겨집니다. false 인 경우, 텍스트 필드는 패스워드 텍스트 필드로서 다루어지지 않습니다. 패스워드 모드를 유효하게 하면,[컷] 커멘드와 [복사] 커멘드, 및 거기에 대응하는 키보드 쇼트 컷이 기능하지 않게 됩니다. 이 시큐러티 기능에 의해, 유저의 부재시에 키보드 쇼트 컷을 사용해 악질적인 유저가 패스워드를 훔치는 것을 방지할 수 있습니다.

디폴트치false.

포함(Embed)되어 있는 폰트의 아우트라인을 사용해 렌더링 할지 어떨지를 지정합니다. false 인 경우는, 디바이스 폰트를 사용해 텍스트 필드를 렌더링 합니다.

텍스트 필드의 embedFonts property를 true 로 설정하는 경우, 텍스트 필드에 적용되는 TextFormat object의 font property를 사용해, 그 텍스트의 폰트를 지정할 필요가 있습니다. 지정한 폰트가 SWF 파일에 포함되지 않은 경우, 텍스트는 표시되지 않습니다.

디폴트치false.

See also

이 텍스트 필드에 사용되는 grid fitting의 타입입니다. 이 property는, 텍스트 필드의 flash.text.AntiAliasType property가 flash.text.AntiAliasType.ADVANCED 로 설정되어 있는 경우에게만 적용됩니다.

사용되는 grid fitting의 타입에 의해, 굵은 수평선과 수직선이 픽셀 grid 또는 서브 픽셀 격자에 합쳐질까 합쳐지지 않는가가 결정됩니다.

flash.text.GridFitType property에서는, 다음의 string치를 사용할 수 있습니다.

디폴트치pixel.

See also

텍스트 필드의 내용을 HTML 로 가리킵니다.

Flash Player 에서는, 다음의 HTML 태그가 지원(support)되고 있습니다.

Flash Player 에서는, 다음의 HTML 엔티티가 지원(support)되고 있습니다.

Flash 에서는 또, & (ASCII 의 ampersand(&))나 € (Unicode 의 € 심볼) 등, 문자 코드의 명시적인 지정도 지원(support)되고 있습니다.

See also

비교를 위해서(때문에), tf2 라고 하는 다른 TextField 에 대해서 같은 순서를 실행합니다. 이 때,tf2 의 styleSheet property에 StyleSheet object를 할당합니다. 이 할당은,htmlText property를 설정하기 전에 실시합니다. 이 때, htmlText property가 트레이스 되는 경우, 이 property에는 최초로 htmlText property에 할당할 수 있고 있던 정확한 HTML 텍스트만이 포함됩니다. 이것은, Flash Player 에 의해 태그가 추가되어 있지 않은 것을 나타냅니다.

package {
    import flash.display.Sprite;
    import flash.text.StyleSheet;
    import flash.text.TextField;

    public class TextField_text extends Sprite {
        public function TextField_text() {
            var tf1:TextField = createTextField(10, 10, 400, 22);
            tf1.htmlText = "<b>Lorem ipsum dolor sit amet. </b>";

            // htmlText: <P ALIGN="LEFT"><FONT FACE="Times New Roman" SIZE="12" COLOR="#000000" LETTERSPACING="0" KERNING="0">&lt;b&gt;Lorem ipsum dolor sit amet. &lt;/b&gt;</FONT></P>
            trace("htmlText: " + tf1.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf1.text);
            
            var tf2:TextField = createTextField(10, 50, 400, 22);
            tf2.styleSheet = new StyleSheet();
            tf2.htmlText = "<b>Lorem ipsum dolor sit amet. </b>";
            // htmlText: <b>Lorem ipsum dolor sit amet. </b>
            trace("htmlText: " + tf2.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf2.text);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

텍스트 필드내의 캐릭터수입니다. 탭 (\t)등의 캐릭터도 1 캐릭터로서 카운트 됩니다.

유저가 입력할 경우에, 텍스트 필드에 들어가는 최대의 캐릭터수입니다. 스크립트는 maxChars 의 허용수를 넘는 텍스트를 삽입할 수 있습니다. maxChars property로 지정되는 것은, 유저가 입력할 수 있는 텍스트의 양 뿐입니다. 이 property의 값이 null 인 경우, 유저가 입력할 수 있는 텍스트의 양에는 제한이 없습니다.

scrollH 의 최대치입니다.

See also

scrollV 의 최대치입니다.

See also

복수행에 걸치는 텍스트 필드로, 유저가 텍스트 필드를 클릭해 휠을 회전시키면, 자동적으로 스크롤 할지 어떨지를 나타내는 불리언 값입니다. 디폴트치는 true 입니다. 이 property는, 마우스 휠로 텍스트 필드를 스크롤 하지 않는 경우나, 텍스트 필드의 스크롤을 독자적으로 Implements하는 경우에 편리합니다.

텍스트 필드가 복수행 텍스트 필드일지 어떨지를 나타냅니다. 값이 true 인 경우는 복수행 텍스트 필드, 값이 false 인 경우는 단일행 텍스트 필드입니다.

디폴트치false.

See also

복수행 텍스트 필드내의 텍스트행의 수를 정의합니다. wordWrap property가 true 로 설정되어 있는 경우, 텍스트가 되접어 꺾이면 행수는 증가합니다.

See also

유저가 텍스트 필드에 입력할 수 있는 캐릭터를 지정합니다. restrict property의 값이 null 인 경우는, 임의의 캐릭터를 입력할 수 있습니다. restrict property의 값이 empty의 string인 경우는, 어느 캐릭터도 입력할 수 없습니다. restrict property의 값이 캐릭터의 string인 경우는, 그 string내의 캐릭터만을 텍스트 필드에 입력할 수 있습니다. string는 왼쪽에서 오른쪽에 스캔 됩니다. 하이픈 (-) 캐릭터를 사용해, 범위를 지정할 수 있습니다. 이것은 유저의 조작만을 제한합니다. 스크립트는 임의의 텍스트를 텍스트 필드에 입력할 수 있습니다. 이 property는, 프로파티인스페크타의 포함(Embed)되어 있는 폰트의 옵션과 동기 하지 않습니다.

string가 caret (^) 캐릭터로 시작되는 경우, 그 string에 포함되는 캐릭터를 제외해, 모든 캐릭터를 입력할 수 있습니다. string가 caret (^) 캐릭터 이외로 시작되는 경우는, 그 string에 포함되는 캐릭터만을 입력할 수 있습니다.

다음의 예에서는, 대문자, 스페이스, 및 수치만을 텍스트 필드에 입력할 수 있습니다.

my_txt.restrict = "A-Z 0-9";
  

다음의 예에서는, 소문자를 제외한 모든 캐릭터를 입력할 수 있습니다.

my_txt.restrict = "^a-z";
  

엔기호를 사용해 ^ 또는 - 의 리터럴을 입력할 수 있습니다. 허용 되는 엔기호의 순차 순서는 \-,\^, 또는 \\ 입니다. 엔기호를 string의 1 캐릭터로서 실제로 사용하려면 , ActionScript 로 지정할 경우에 엔기호를 2 개 계속해 지정할 필요가 있습니다. 예를 들어, 다음의 코드로 나타내지고 있는 것은 데쉬 (-)와 caret (^) 뿐입니다.

my_txt.restrict = "\\-\\^";
  

string내에서는 임의의 장소에서 ^ 를 사용해, 입력할 수 있는 캐릭터와 제외하는 캐릭터를 바꿀 수가 있습니다. 다음의 코드에서는, 대문자만을 입력할 수 있습니다. 다만, 대문자의 Q 를 제외합니다.

my_txt.restrict = "A-Z^Q";
  

u escape sequence를 사용해,restrict string를 구축할 수 있습니다. 다음의 코드에서는, ASCII 32 (스페이스)로부터 ASCII 126 (치르다)까지의 캐릭터만을 입력할 수 있습니다.

my_txt.restrict = " -~";
  

디폴트치null.

현재의 수평 스크롤 위치입니다. scrollH property가 0 인 경우, 텍스트는 수평에 스크롤 되지 않습니다. 이 property의 값은, 수평 위치를 픽셀 단위로 나타내는 정수입니다.

텍스트의 스크롤의 상세한 것에 대하여는, 「ActionScript 3.0 의 프로그래밍」을 참조해 주세요.

수직 스크롤의 단위는 행수입니다만, 수평 스크롤의 단위는 픽셀수입니다. 수평 스크롤을 픽셀 단위로 지정하는 것은, 일반적으로 사용되는 폰트의 대부분이 proportional font이며, 캐릭터의 폭이 일정이 아니기 때문입니다. 수직 스크롤의 경우는, 통상, 1 행의 텍스트의 일부만 표시되는 것보다도 행 전체가 표시되는 것이 선호되기 (위해)때문에, 행 단위로 스크롤 합니다. 1 행안에 복수의 폰트가 존재하는 경우에서도, 사용되고 있는 최대의 폰트에 맞추어 행의 높이가 조정됩니다.

메모 :scrollH property는,scrollV 수직 스크롤 property와 같이 1 으로부터 시작되는 것이 아니라, 0 으로부터 시작됩니다.

See also

텍스트 필드의 텍스트의 수직 좌표입니다. scrollV property는, 긴 문절내의 특정의 단락에 유저를 유도하거나 스크롤 텍스트 필드를 작성하거나 하는 경우에 편리합니다.

수평 스크롤의 단위는 픽셀수입니다만, 수직 스크롤의 단위는 행수입니다. 표시되는 최초의 행이 텍스트 필드내의 최초의 행의 경우, scrollV 는 1 으로 설정됩니다. 0 이 아닙니다. 수평 스크롤을 픽셀 단위로 지정하는 것은, 폰트의 대부분이 proportional font이며, 캐릭터의 폭이 일정이 아니기 때문입니다. 수직 스크롤의 경우는, 통상, 1 행의 텍스트의 일부만 표시되는 것보다도 행 전체가 표시되는 것이 선호되기 (위해)때문에, 행 단위로 스크롤 합니다. 1 행안에 복수의 폰트가 존재하는 경우에서도, 사용되고 있는 최대의 폰트에 맞추어 행의 높이가 조정됩니다.

See also

텍스트 필드가 선택 가능한지 어떤지를 나타내는 불리언 값입니다. 값 true 는, 텍스트가 선택 가능한 것을 나타냅니다. selectable property를 사용하는 것으로, 텍스트 필드가 선택 가능한가 어떤가를 지정할 수 있습니다만, 편집 가능한가 어떤가는 지정할 수 없습니다. 다이나믹 텍스트 필드는, 편집 가능하지 않은 경우에서도 선택 가능하게 할 수가 있습니다. 다이나믹 텍스트 필드가 선택 가능하지 않은 경우, 유저는 필드내의 텍스트를 선택할 수 없습니다.

selectable 를 false 로 설정하면, 텍스트 필드내의 텍스트는 마우스나 키보드로부터의 선택 커멘드에 응답하지 않게 되어,[복사] 커멘드를 사용해 텍스트를 복사할 수가 없게 됩니다. selectable 를 true 로 설정하면, 텍스트 필드내의 텍스트는 마우스나 키보드를 사용해 선택할 수 있게 되어,[복사] 커멘드를 사용해 텍스트를 복사할 수 있게 됩니다. 텍스트 입력 필드는 아니고 다이나믹 텍스트 필드의 경우에서도, 이 방법으로 텍스트를 선택할 수 있습니다.

디폴트치true.

See also

현재의 선택 범위의 최초의 캐릭터를 나타내는 0 베이스의 인덱스치입니다. 최초의 캐릭터가 0, 2 번째의 캐릭터가 1 입니다 (이하 같이). 텍스트가 선택되어 있지 않은 경우, 이 property는 caretIndex 의 값이 됩니다.

See also

이 예를 실행해, TextField 를 클릭해 텍스트의 선택을 시도합니다. 다음에, 텍스트를 선택하지 않고 필드를 클릭합니다. 선택하지 않고 텍스트를 클릭했을 경우, caretIndex property는 커서가 표시되는 위치를 나타내, selectionBeginIndex selectionEndIndex property는 caretIndex property의 값과 동일해집니다.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field.  Compare the difference between clicking without selecting versus clicking and selecting text. ";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent) :void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

현재의 선택 범위에 있어서의 마지막 캐릭터를 나타내는, 0 으로부터 시작되는 인덱스치입니다. 최초의 캐릭터가 0, 2 번째의 캐릭터가 1 입니다 (이하 같이). 텍스트가 선택되어 있지 않은 경우, 이 property는 caretIndex 의 값이 됩니다.

See also

이 예를 실행해, TextField 를 클릭해 텍스트의 선택을 시도합니다. 다음에, 텍스트를 선택하지 않고 필드를 클릭합니다. 선택하지 않고 텍스트를 클릭했을 경우, caretIndex property는 커서가 표시되는 위치를 나타내, selectionBeginIndex selectionEndIndex property는 caretIndex property의 값과 동일해집니다.

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field.  Compare the difference between clicking without selecting versus clicking and selecting text. ";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent) :void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

이 텍스트 필드내의 캐릭터 엣지의 샤프니스입니다. 이 property는, 텍스트 필드의 flash.text.AntiAliasType property가 flash.text.AntiAliasType.ADVANCED 로 설정되어 있는 경우에게만 적용됩니다. sharpness 의 범위는 -400 ~ 400 의 수치입니다. sharpness 를 이 범위외의 값으로 설정하려고 하면, 이 property는 범위내의 가장 가까운 값 (-400 또는 400)으로 설정됩니다.

디폴트치0.

See also

텍스트 필드에 스타일 시트를 관련짓습니다. 스타일 시트의 작성의 상세한 것에 대하여는, StyleSheet 클래스 및 「ActionScript 3.0 의 프로그래밍」을 참조해 주세요.

텍스트 필드에 관련지을 수 있고 있는 스타일 시트는, 언제라도 변경할 수가 있습니다. 사용되고 있는 스타일 시트를 변경하면, 텍스트 필드는 새로운 스타일 시트를 사용해 재묘화 됩니다. 스타일 시트를 null 또는 undefined 로 설정하면, 그 스타일 시트를 삭제할 수 있습니다. 스타일 시트를 삭제하면, 텍스트 필드는 스타일 시트를 사용하지 않고 재묘화 됩니다. 스타일 시트가 삭제되었을 경우, 스타일 시트가 적용하는 포맷 설정은 보관 유지되지 않습니다.

See also

텍스트 필드내의 현재의 텍스트인 string입니다. 행은 복귀 캐릭터 ('\r', ASCII 13)로 단락지어집니다. 이 property는, HTML 태그가 붙지 않은, 텍스트 필드내의 포맷 없음의 텍스트를 나타냅니다.

HTML 폼내의 텍스트를 취득하려면 ,htmlText property를 사용합니다.

See also

비교를 위해서(때문에), tf2 라고 하는 다른 TextField 에 대해서 같은 순서를 실행합니다. 이 때,tf2 의 styleSheet property에 StyleSheet object를 할당합니다. 이 할당은,htmlText property를 설정하기 전에 실시합니다. 이 때, htmlText property가 트레이스 되는 경우, 이 property에는 최초로 htmlText property에 할당할 수 있고 있던 정확한 HTML 텍스트만이 포함됩니다. 이것은, Flash Player 에 의해 태그가 추가되어 있지 않은 것을 나타냅니다.

package {
    import flash.display.Sprite;
    import flash.text.StyleSheet;
    import flash.text.TextField;

    public class TextField_text extends Sprite {
        public function TextField_text() {
            var tf1:TextField = createTextField(10, 10, 400, 22);
            tf1.htmlText = "<b>Lorem ipsum dolor sit amet. </b>";

            // htmlText: <P ALIGN="LEFT"><FONT FACE="Times New Roman" SIZE="12" COLOR="#000000" LETTERSPACING="0" KERNING="0">&lt;b&gt;Lorem ipsum dolor sit amet. &lt;/b&gt;</FONT></P>
            trace("htmlText: " + tf1.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf1.text);
            
            var tf2:TextField = createTextField(10, 50, 400, 22);
            tf2.styleSheet = new StyleSheet();
            tf2.htmlText = "<b>Lorem ipsum dolor sit amet. </b>";
            // htmlText: <b>Lorem ipsum dolor sit amet. </b>
            trace("htmlText: " + tf2.htmlText);
            // text: Lorem ipsum dolor sit amet.
            trace("text: " + tf2.text);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

텍스트 필드의 텍스트의 색입니다 (16 진수 형식). 16 진수 칼라 시스템에서는, 6 자리수의 수치를 사용해 색의 값을 나타냅니다. 1 개의 자리수로, 16 종류의 값 (캐릭터)을 지정할 수 있습니다. 값의 범위는, 0 ~ 9, A ~ F 입니다. 예를 들어, 흑은 (0x000000), 흰색은 (0xFFFFFF)입니다.

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textColor extends Sprite {
        public function TextField_textColor() {
            var tf:TextField = createTextField(10, 10, 100, 300);
            tf.text = "This will be red text";
            tf.textColor = 0xFF0000;            
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

텍스트의 높이입니다 (픽셀 단위).

See also

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textHeight extends Sprite {
        public function TextField_textHeight() {
            var tf:TextField = createTextField(10, 10, 100, 150);
            tf.text = "Sample text";
            
            trace("textWidth: " + tf.textWidth); // textWidth: 55.75
            trace("textHeight: " + tf.textHeight); // textHeight: 13.450000000000001
            trace("width: " + tf.width); // width: 100
            trace("height: " + tf.height); // height: 150
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            result.background = true;
            addChild(result);
            return result;
        }
    }
}

텍스트의 폭입니다 (픽셀 단위).

See also

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_textHeight extends Sprite {
        public function TextField_textHeight() {
            var tf:TextField = createTextField(10, 10, 100, 150);
            tf.text = "Sample text";
            
            trace("textWidth: " + tf.textWidth); // textWidth: 55.75
            trace("textHeight: " + tf.textHeight); // textHeight: 13.450000000000001
            trace("width: " + tf.width); // width: 100
            trace("height: " + tf.height); // height: 150
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            result.background = true;
            addChild(result);
            return result;
        }
    }
}

이 텍스트 필드내의 캐릭터 엣지의 굵기입니다. 이 property는,flash.text.AntiAliasType 가 flash.text.AntiAliasType.ADVANCED 로 설정되어 있는 경우에게만 적용됩니다.

thickness 의 범위는 -200 ~ 200 의 수치입니다. thickness 를 이 범위외의 값으로 설정하려고 하면, 이 property는 범위내의 가장 가까운 값 (-200 또는 200)으로 설정됩니다.

디폴트치0.

See also

텍스트 필드의 타입입니다. 다음의 TextFieldType 정수의 머지않아인가입니다. TextFieldType.DYNAMIC 는 다이나믹 텍스트 필드를 지정합니다. 이 필드를 유저가 편집할 수 없습니다. TextFieldType.INPUT 는 텍스트 입력 필드를 지정합니다. 이 필드는 유저가 편집할 수 있습니다.

디폴트치dynamic.

See also

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_type extends Sprite {
        public function TextField_type() {
            var tfDynamic:TextField = createTextField(10, 10, 100, 20);
            tfDynamic.type = TextFieldType.DYNAMIC;
            tfDynamic.text = "hello";

            var tfInput:TextField = createTextField(10, 45, 100, 20);
            tfInput.type = TextFieldType.INPUT;
            tfInput.text = "world";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.background = true;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

텍스트와 함께 텍스트의 포맷을 복사 & 붙혀넣기 할지 어떨지를 지정합니다. true 로 설정되어 있는 경우, 텍스트 필드간에 복사 & 붙혀넣기를 실시하면, Flash Player 에 의해 포맷 (행 가지런히 해 볼드, 이탤릭등)도 복사 & 붙혀넣기 됩니다. 복사 & 붙혀넣기 순서의 복사원과 붙혀넣기처의 텍스트 필드의 양쪽 모두로,useRichTextClipboard 가 true 로 설정되어 있을 필요가 있습니다. 디폴트치는 false 입니다.

텍스트 필드의 텍스트를 되풀이할지 어떨지를 나타내는 불리언 값입니다. wordWrap 의 값이 true 인 경우는, 텍스트 필드의 텍스트를 되풀이해,false 인 경우는 되풀이하지 않습니다. 디폴트치는 false 입니다.

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_wordWrap extends Sprite {
        public function TextField_wordWrap() {
            var tfWrap:TextField = createTextField(10, 10, 100, 100);
            tfWrap.wordWrap = true;
            tfWrap.text = "(wordWrap = true) :\nThis is very long text that will certainly extend beyond the width of this text field";

            var tfNoWrap:TextField = createTextField(10, 150, 100, 100);
            tfNoWrap.wordWrap = false;
            tfNoWrap.text = "(wordWrap = false) :\nThis is very long text that will certainly extend beyond the width of this text field";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number) :TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.background = true;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

새로운 TextField 인스턴스를 작성합니다. TextField 인스턴스의 작성 후, 친 DisplayObjectContainer object의 addChild() Methods 또는 addChildAt() Methods를 호출해, TextField 인스턴스를 표시 리스트에 추가합니다.

newText Parameters로 지정된 string를, TextField 의 텍스트의 마지막에 부가합니다.

캐릭터의 경계 박스인 구형을 돌려줍니다.

See also

x 및 y Parameters로 지정된 포인트에 있는 캐릭터의 인덱스치 (0 으로부터 시작된다)를 돌려줍니다.

캐릭터 인덱스를 지정하면, 같은 단락내의 최초의 캐릭터의 인덱스를 돌려줍니다.

<img> 태그를 사용해 HTML 포맷의 텍스트 필드에 추가된 이미지 또는 SWF 파일에 대해, 지정된 id 의 DisplayObject 참조를 돌려줍니다. <img> 태그는 다음의 형식입니다.

 <img src = 'filename.jpg' id = 'instanceName' >

See also

x 및 y Parameters로 지정된 포인트에 있는 행의 인덱스치 (0 으로부터 시작된다)를 돌려줍니다.

charIndex Parameters로 지정된 캐릭터를 포함한 행의 인덱스치 (0 으로부터 시작된다)를 돌려줍니다.

특정의 텍스트 은행내의 캐릭터수를 돌려줍니다.

지정된 텍스트행에 관한 시학 정보를 돌려줍니다.

See also

lineIndex Parameters로 지정된 행의 최초의 캐릭터의 캐릭터 인덱스를 돌려줍니다.

lineIndex Parameters로 지정된 행의 텍스트를 돌려줍니다.

캐릭터 인덱스를 지정하면, 지정된 캐릭터를 포함한 단락의 길이를 돌려줍니다. 이 길이는, 건네받은 캐릭터 인덱스는 아니고, 단락내의 최초의 캐릭터에 대응합니다. getFirstCharInParagraph() 에 의해 돌려주어지는 경우와 같습니다.

See also

beginIndex 및 endIndex Parameters로 지정된 범위의 텍스트의 포맷 정보를 포함한 TextFormat object를 돌려줍니다. 지정된 텍스트 전체에 공통되는 property만이, 결과의 TextFormat object로 설정됩니다. 혼재형의 property (텍스트에 복수가 다른 값이 혼재하는 경우)는, 그 값이 null 로 설정됩니다.

이러한 Parameters에 값을 지정하지 않는 경우, 이 Methods는 텍스트 필드내의 모든 텍스트에 적용됩니다.

다음의 겉(표)에, 사용할 수 있는 3 개의 문장구조법을 나타냅니다.

See also

현재의 선택 내용을 value Parameters의 내용에 옮겨놓습니다. 텍스트는, 현재의 디폴트의 캐릭터 포맷과 디폴트의 단락 포맷을 사용해, 현재의 선택 내용의 위치에 삽입됩니다. 텍스트는 HTML 로서 다루어지지 않습니다.

replaceSelectedText() Methods를 사용하면, 다른 부분의 텍스트의 캐릭터 포맷 및 단락 포맷을 해치지 않고 텍스트를 삽입 및 삭제할 수 있습니다.

See also

beginIndex Parameters와 endIndex Parameters로 지정된 캐릭터 범위를,newText Parameters의 내용에 옮겨놓습니다.

최초의 캐릭터와 마지막 캐릭터의 인덱스치에 의해 지정된 텍스트를 선택 끝나로 설정합니다. 최초의 캐릭터와 마지막 캐릭터의 인덱스치는,beginIndex 및 endIndex Parameters를 사용해 지정되고 있습니다. 2 개의 Parameters치가 같은 경우는,caretIndex property를 설정했을 경우와 같게, 이 Methods는 삽입 포인트를 설정합니다.

See also

format Parameters로 지정한 텍스트 포맷을, 텍스트 필드내의 지정된 텍스트에 적용합니다. format 의 값은, 필요한 텍스트 포맷의 변경을 지정하는 TextFormat object일 필요가 있습니다. format 의 null 이외의 property만이, 텍스트 필드에 적용됩니다. format 로 null 로 설정되어 있는 property는 적용되지 않습니다. 디폴트로, 새롭게 작성된 TextFormat object의 property는 모두 null 로 설정됩니다.

setTextFormat() Methods는, 텍스트 필드의 캐릭터의 범위 또는 텍스트 전체에 적용하는 텍스트 포맷을 변경합니다. 포맷의 property를 텍스트 필드내의 모든 텍스트에 적용하려면 ,beginIndex 및 endIndex 에 값을 지정하지 말아 주세요. 포맷의 property를 텍스트의 범위에 적용하려면 ,beginIndex 및 endIndex Parameters에 값을 지정합니다. length property를 사용해, 인덱스치를 지정할 수 있습니다.

TextFormat object의 포맷 정보에는, 캐릭터 레벨 포맷과 단락 레벨 포맷의 2 종류가 있습니다. 텍스트 필드내의 각 캐릭터에도, 폰트명이나 font size, 볼드, 이탤릭등의 캐릭터 고유의 포맷 설정이 있습니다.

단락의 경우는, 단락의 최초의 캐릭터를 조사해 단락 전체의 포맷 설정을 결정합니다. 단락의 포맷 설정에는, 왼쪽 마진, 오른쪽 마진, 인덴트등이 있습니다.

유저에 의해 수작업으로 삽입된 텍스트, 또는 replaceSelectedText() Methods를 사용해 옮겨놓을 수 있었던 텍스트는, 텍스트의 삽입이나 곳으로 지정되고 있는 포맷은 아니고, 새로운 텍스트용의 텍스트 필드의 디폴트 포맷이 적용됩니다. 새로운 텍스트용의 텍스트 필드의 디폴트 포맷을 설정하려면 ,defaultTextFormat 를 사용합니다.

See also

컨트롤의 값이 변경된 후에 dispatch됩니다. 값이 변경되기 전에 dispatch되는 textInput 이벤트와는 대조적입니다. 컨트롤이 포커스를 잃은 다음에 전용 이벤트를 dispatch하는 change 이벤트의 W3C DOM Event Model 버젼과는 달라,change 이벤트의 ActionScript 3.0 버젼은 컨트롤이 변경되었을 때에 dispatch됩니다. 예를 들어, 유저가 텍스트 필드에 텍스트를 입력하면, 키스트로크(keystroke)마다 change 이벤트가 dispatch됩니다.

change event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

HTML 가 유효하게 되어 있는 텍스트 필드의 하이퍼 링크를 유저가 클릭했을 때에 dispatch됩니다 (URL 는 "event:" 로 시작됩니다). "event:" 의 뒤의 URL 의 나머지의 부분은, LINK 이벤트의 text property내에 배치됩니다.

메모:디폴트의 동작인 텍스트 필드에의 텍스트의 추가는, Flash Player 가 이벤트를 생성할 경우에만 발생합니다. 이 경우에서는, 유저가 텍스트를 입력하려고 할 때입니다. textInput 이벤트에 송신하는 것에 의해 텍스트 필드에 텍스트를 입력할 수 없습니다.

link event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

package {
    import flash.display.Sprite;
    import flash.errors.IOError;
    import flash.events.IOErrorEvent;
    import flash.events.TextEvent;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.net.URLRequest;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class TextField_event_link extends Sprite
    {
        private var myMP3:Sound;
        public function TextField_event_link() {
            myMP3 = new Sound();
            var list:TextField = new TextField();
            list.autoSize = TextFieldAutoSize.LEFT;
            list.multiline = true;
            list.htmlText = "<a href=\"event:track1.mp3\">Track 1</a><br>";
            list.htmlText += "<a href=\"event:track2.mp3\">Track 2</a><br>";
            addEventListener(TextEvent.LINK, linkHandler);
            addChild(list);
        }
        
        private function playMP3(mp3:String) :void {
            try {    
                myMP3.load(new URLRequest(mp3));
                myMP3.play();
            }
            catch(err:Error) {
                trace(err.message);
            }
            myMP3.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
        }
        
        private function linkHandler(linkEvent:TextEvent) :void {
            playMP3(linkEvent.text);
        }
        
        private function errorHandler(errorEvent:IOErrorEvent) :void {
            trace(errorEvent.text);
        }
    }
}

유저가 스크롤 한후에, TextField object에 의해 dispatch됩니다.

scroll event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

Flash Player 에서는, 유저가 텍스트의 캐릭터를 입력했을 때에 textInput 이벤트를 dispatch합니다. 다수가 다른 텍스트 입력 Methods에 의해, 이 이벤트가 생성됩니다. 표준 키보드, IME (입력 Methods 에디터), 음성인식 시스템, 서식이나 스타일의 정보를 가지지 않는 plaintext의 붙혀넣기 조작 등입니다.

textInput event object의 type property의 값을 정의합니다.

이 이벤트에는, 다음의 property가 있습니다.

1. 타입 TextField 의 label property가 작성됩니다.
2. 클래스 constructor　 　 은 configureLabel() 함수를 호출합니다.
3. configureLabel() Methods는, 최초로 새로운 TextField object를 작성해, 그것을 label property에 할당해 다음에 그 Parameters를 이하와 같이 설정합니다.
• 텍스트 필드를 왼쪽 가지런히 해로 합니다.
• 배경의 칠을 유효하게 합니다.
• 경계선을 유효하게 합니다.
4. configureLabel() Methods는,format 변수를 작성해, 그것을 새로운 TextFormat 인스턴스에 할당합니다. Parameters를 이하와 같이 설정합니다.
• Font type = Veranda
• Font color = solid red
• Font size = 10
• Font underline = true
5. label 텍스트 필드의 defaultTextFormat property 하지만 format 로 설정되어label 인스턴스가 표시 리스트에 추가됩니다. 처음은, 표시 리스트에는 스테이지상에 텍스트가 없는 텍스트 필드가 표시되고 있습니다.
6. constructor　 　 은,label 텍스트 필드의 텍스트를 "Hello world and welcome to the show. " (으)로 설정합니다. 그 때문에(위해), setLabel() Methods를 경유해 제공되는 정보가 출력됩니다.

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;


    public class TextFieldExample extends Sprite {
        private var label:TextField;
        private var labelText:String = "Hello world and welcome to the show. ";

        public function TextFieldExample() {
            configureLabel();
            setLabel(labelText);
        }

        public function setLabel(str:String) :void {
            label.text = str;
        }

        private function configureLabel() :void {
            label = new TextField();
            label.autoSize = TextFieldAutoSize.LEFT;
            label.background = true;
            label.border = true;

            var format:TextFormat = new TextFormat();
            format.font = "Verdana";
            format.color = 0xFF0000;
            format.size = 10;
            format.underline = true;

            label.defaultTextFormat = format;
            addChild(label);
        }
    }
}